VBS访问剪贴板的几种方法小结

所属分类: 脚本专栏 / vbs 阅读数: 1420
收藏 0 赞 0 分享
复制代码 代码如下:

Set IE = CreateObject("InternetExplorer.Application")
IE.Navigate("about:blank")
Set clipboard = IE.document.parentWindow.clipboardData
'SetData设置剪切板的内容
clipboard.SetData "text", "忘记了,喜欢一个人的感觉"
'GetData获取剪切板的内容
WScript.Echo clipboard.GetData("text")
IE.Quit

实践证明,网上一搜一大把的代码一般不是好代码。SetData方法其实是和IE浏览器的设置有关的。

ie

IE8的默认设置是Prompt,所以运行上面那个脚本的时候会弹出一个对话框,如果这是成Disable,那么这个脚本就无法设置剪贴板内容了(获取不受影响)。

prompt

这种没有保证的代码还是少用一些的好,在Windows 7下可以用clip.exe来设置剪贴板的内容,获取的话还是用IE就行了。

Dim WshShell
set WshShell = CreateObject("wscript.Shell")
str = "忘记了,喜欢一个人的感觉"
WshShell.Run "cmd.exe /c echo " & str & " | clip",0,False

用Word.Application也可以设置和获取剪贴板内容

'设置剪切板的内容
Dim Word
Set Word = CreateObject("Word.Application")
Word.Documents.Add
Word.Selection.Text = "忘记了,喜欢一个人的感觉"
Word.Selection.Copy
Word.Quit False
'获取剪切板的内容
Dim Word
Set Word = CreateObject("Word.Application")
Word.Documents.Add
Word.Selection.PasteAndFormat(wdFormatPlainText)
Word.Selection.WholeStory
str = Word.Selection.Text
Word.Quit False
WScript.Echo str

最神奇的是用Microsoft Forms 2.0 Object Library。

'设置剪切板的内容
Dim Form, TextBox
Set Form = CreateObject("Forms.Form.1")
Set TextBox = Form.Controls.Add("Forms.TextBox.1").Object
TextBox.MultiLine = True
TextBox.Text = "忘记了,喜欢一个人的感觉"
TextBox.SelStart = 0
TextBox.SelLength = TextBox.TextLength
TextBox.Copy
'获取剪切板的内容
Dim Form, TextBox
Set Form = CreateObject("Forms.Form.1")
Set TextBox = Form.Controls.Add("Forms.TextBox.1").Object
TextBox.MultiLine = True
If TextBox.CanPaste Then
 TextBox.Paste
 WScript.Echo TextBox.Text
End If

参考链接:

  1. [UMU WSH 教程](30) 访问剪贴板
  2. [UMU WSH 教程](32) 访问剪贴板(2)

原文:http://demon.tw/programming/vbs-clipboard.html
更多精彩内容其他人还在看

可以将Bat转换位VBS文件的VBS脚本

可以将Bat转换位VBS文件的VBS脚本
收藏 0 赞 0 分享

用vbs实现cmd功能

用vbs实现cmd功能
收藏 0 赞 0 分享

VBS编程教程 (第1篇)

VBS编程教程 (第1篇)
收藏 0 赞 0 分享

VBS编程教程 (第2篇)

VBS编程教程 (第2篇)
收藏 0 赞 0 分享

VBS编程教程 (第3篇)

VBS编程教程 (第3篇)
收藏 0 赞 0 分享

VBS编程教程 (第4篇)

VBS编程教程 (第4篇)
收藏 0 赞 0 分享

VBS编程教程 (第5篇)

VBS编程教程 (第5篇)
收藏 0 赞 0 分享

VBS编程教程 (第6篇)

今天我们学习基础篇的最后一个部分:自定义函数和过程. 我们每天都在和函数打交道, inputbox()是函数, msgbox()是函数, int()也是函数...这些函数都是系统内建的, 我们只能用不能改. 今天我就教大家怎样自己制作一个函数
收藏 0 赞 0 分享

用VBS可执行程序+Xmlhttp下载备份网上文件的代码

用VBS可执行程序+Xmlhttp下载备份网上文件的代码
收藏 0 赞 0 分享

注册表-批处理-VBS之间的相互结合应用第1/2页

注册表-批处理-VBS之间的相互结合应用
收藏 0 赞 0 分享
查看更多